BMUG Revelations/BMUG Revelations.toast/Telecom/Scripts/ARA SupraFaxModem Scripts/SupraFaxModem v.32 bis/SupraFaxModem v.32 bis

Text File | 1992-04-08 | 3KB | 175 lines

! "Supra SupraFaxModem v.32bis - 4/8/91"
! "Written by Steve Kruse "
@ORIGINATE
@ANSWER
!
@LABEL 1
serreset 57600, 0, 8, 1
!
! first recall the factory configuration
!
matchclr
settries 0
matchstr 1 3 "OK\13\10"
@LABEL 2
write "AT&F1\13"
matchread 30
inctries
iftries 2 59
jump 2
!
! Next, Set up the configuration: Echo off.
!
@LABEL 3
matchstr 1 5 "OK\13\10"
write "ATE0\13"
matchread 30
jump 59
!
! If speaker on flag is true, jump to label 8.  Else turn off the speaker
!
@LABEL 5
matchclr
ifstr 2 8 "1"
matchstr 1 8 "OK\13\10"
write "ATM0\13"
matchread 30
jump 59
!
! The modem is ready.  So enable answering, or originate a call
! Mickey Mouse has big ears.
! Donald Duck has big feet.
@LABEL 8
ifANSWER 30
note "Dialing ^1" 3
write "ATDT^1\13"
!
@LABEL 9
matchstr  1 11 "CONNECT 14400\13\10"
matchstr  2 12 "CONNECT 57600\13\10"
matchstr  3 13 "CONNECT 9600\13\10"
matchstr  4 14 "CONNECT 2400\13\10"
matchstr  5 50 "NO CARRIER\13\10"
matchstr  6 50 "ERROR\13\10"
matchstr  7 52 "NO DIALTONE\13\10"
matchstr  8 53 "BUSY\13\10"
matchstr  9 54 "NO ANSWER\13\10"
matchread 700
jump 59
!
@LABEL 11
note "Communicating at 14400 bps." 2
serreset 14400, 0, 8, 1
jump 16
!
@LABEL 12
note "Communicating at 57600 bps." 2
serreset 57600, 0, 8, 1
jump 16
!
@LABEL 13
note "Communicating at 9600 bps." 2
serreset 9600, 0, 8, 1
jump 16
!
@LABEL 14
note "Communicating at 2400 bps." 2
serreset 2400, 0, 8, 1
jump 16
!
@LABEL 16
ifANSWER 17
pause 30
@LABEL 17
exit 0
!
! @ANSWER
! Set up the modem to answer
@LABEL 30
write "ATS0=1\13"
matchstr 1 31 "OK\13\10"
matchread 30
jump 59
!
@LABEL 31
matchstr 1  32 "RING\13\10"
matchstr 2  11 "CONNECT 14400\13\10"
matchstr 3  12 "CONNECT 57600\13\10"
matchstr  4 13 "CONNECT 9600\13\10"
matchstr  5 14 "CONNECT 2400\13\10"
matchstr 6  50 "NO CARRIER\13\10"
matchstr 7  50 "ERROR\13\10"
matchstr 8  52 "NO DIALTONE\13\10"
matchstr 9  53 "BUSY\13\10"
matchstr 10  54 "NO ANSWER\13\10"
matchread 700
jump 31
!
@LABEL 32
userhook 1
note "Answering phone…" 2
jump 31
!
! 50: error messages
!
@LABEL 50
exit -6021
!
@LABEL 52
exit -6020
!
@LABEL 53
exit -6022
!
@LABEL 54
exit -6023
!
@LABEL 59
exit -6019
!
! Hang up the modem
!
@HANGUP
@LABEL 60
settries 0
@LABEL 61
write "ATH0\13"
matchclr
matchstr 1 64 "OK\13\10"
matchstr 2 64 "NO CARRIER\13\10"
matchstr 3 64 "ERROR\13\10"
matchread 15
inctries
iftries 3 64
! no response, try escape sequence
write "+++"
matchclr
matchstr 1 62 "OK\13\10"
matchread 18
!
! No response from modem, toggle DTR
!
DTRClear
pause 10
DTRSet
jump 61
!
@LABEL 62
matchclr
matchstr 1 64 "OK\13\10"
matchstr 2 64 "NO CARRIER\13\10"
write "ATH0\13"
matchread 50
jump 61
!
! Recall the factory settings for macintosh communications. & Leave Echo On.
!
@LABEL 64
matchclr
matchstr 1 65 "OK\13\10"
write "AT&F1\13"
matchread 30
!
@LABEL 65
exit 0